VBA を整える。

Sub Main()
    Debug.Print "Hello, World!"
End Sub

実行すると

Hello, World!

VBA のプログラムは Sub ～ End Sub の「プロシージャ」単位で書きます。Debug.Print の結果は画面ではなく、VBE のイミディエイトウィンドウ（Ctrl+G）に出ます。

同じお題をほかの言語で： C言語・C++・Java・C#・COBOL

Sub Main()
    Dim i As Long
    For i = 1 To 15
        If i Mod 15 = 0 Then
            Debug.Print "FizzBuzz"
        ElseIf i Mod 3 = 0 Then
            Debug.Print "Fizz"
        ElseIf i Mod 5 = 0 Then
            Debug.Print "Buzz"
        Else
            Debug.Print CStr(i)
        End If
    Next i
End Sub

実行すると

1
2
Fizz
4
Buzz
Fizz
7
8
Fizz
Buzz
11
Fizz
13
14
FizzBuzz

余りは % ではなく Mod 演算子で求めます。Debug.Print i のように正の数をそのまま出すと先頭に空白が1つ付くため、CStr で文字列にしてから出しています。

同じお題をほかの言語で： C言語・C++・Java・C#・COBOL

Sub Main()
    Dim a As Variant
    Dim i As Long
    Dim total As Long
    a = Array(3, 1, 4, 1, 5, 9, 2, 6)
    For i = LBound(a) To UBound(a)
        total = total + a(i)
    Next i
    Debug.Print "合計: " & CStr(total)
    Debug.Print "平均: " & Format(total / (UBound(a) - LBound(a) + 1), "0.00")
End Sub

実行すると

合計: 31
平均: 3.88

Array 関数で作った配列は 0 から始まります。要素数は UBound - LBound + 1 で求めます。平均 3.875 は Format で小数2桁に丸めて 3.88 と表示しています（Format は 5 を切り上げます）。

同じお題をほかの言語で： C言語・C++・Java・C#・COBOL

Sub Main()
    Dim path As String
    Dim f As Integer
    Dim buf As String
    path = Environ("TEMP") & "\memo.txt"

    f = FreeFile
    Open path For Output As #f
    Print #f, "1行目: こんにちは"
    Print #f, "2行目: VBA"
    Close #f

    f = FreeFile
    Open path For Input As #f
    Do Until EOF(f)
        Line Input #f, buf
        Debug.Print buf
    Loop
    Close #f
End Sub

実行すると

1行目: こんにちは
2行目: VBA

Environ("TEMP") は Windows の一時フォルダの場所を返すので、書き込める場所に memo.txt を作れます。Open ... For Output で書き込み（同名ファイルは上書き）、For Input で読み込み、Line Input # で1行ずつ取り出します。FreeFile は空いているファイル番号を返す関数です。

同じお題をほかの言語で： C言語・C++・Java・C#・COBOL

Sub Main()
    Dim a As Long, b As Long, c As Long
    On Error GoTo ErrHandler
    a = 10
    b = 0
    c = a / b
    Debug.Print "ここは表示されません"
    Exit Sub
ErrHandler:
    Debug.Print "エラー番号: " & CStr(Err.Number)
    Debug.Print "処理を終了します"
End Sub

実行すると

エラー番号: 11
処理を終了します

On Error GoTo で、エラーが起きたら指定したラベルへ飛ぶようにします。0 で割るとエラー番号 11 になります。Err.Description の文言は Office の言語や版で変わるため、ここでは番号だけを出しています。正常時に処理部分へ落ちないよう、ラベルの前に Exit Sub を置きます。

同じお題をほかの言語で： C言語・C++・Java・C#・COBOL